電腦領域 HKEPC Hardware - Powered by Discuz! Board

標題: [開箱] 馳為Hi8 pro開箱+改win10單系統(更新2:喚醒筋疲力盡屍體的方法) [打印本頁]

作者: xxxxxx623 時間: 2016-7-24 22:16 標題: 馳為Hi8 pro開箱+改win10單系統(更新2:喚醒筋疲力盡屍體的方法)

本帖最後由 xxxxxx623 於 2018-10-21 23:45 編輯

之前見馳為天貓賣489包keyboard同原裝皮套,而自己又死咗部三叔tablet所以入手
集運計咗1.4kg

盒,原先有包膠

唔知點解淘寶貨用英文貼紙

內容物:機, usb 2.0 type c線,火牛,紙(含正體簡體中文英文說明書)

usb 2.0 type c線,火牛

開機,windows語言有3個

Bluetooth keyboard,micro usb只供充電

原裝皮套,可以夾埋keyboard

個Android感覺好乾淨

唔知點解明明中國機但係部機個Android 有Google play

部機感覺唔錯,但係有幾個大問題

第一個問題就係bios唔support 64bit os(網上啲人話)
明明Z8300 support 64bit 但係bios唔support
所以當我試圖由Windows 10(32bit)去返Windows 8.1(64bit)時,好成功咁整死咗

由於部機只有一個usb port所以無hub時flash disk同keyboard只能揀一個

第二個問題,個bios唔支援用power key, volume up and volume down 去控制
所以當無keyboard時連boot menu 都無法入

第三個問題,個bios唔準改個開機順序之外仲唔識自己boot入usb flash disk
個順序係咁

係呀佢睇落好似可以行到64bit咁

但現實上佢一係入android,一係入windows,係唔識自己boot入usb flash disk入面

由於未有usb hub又玩死咗個windows,所以未試個usb type c係2.0定3.0
各位因usb type c可能係usb 3.0而想買就請務必小心

12-08-2016更新:改成windows單系統方法
有人pm問咁我又答吓啦

改成單 windows 版就只不過係將emmc入面除咗第一個EFI partition, 倒數第二個Windows partition,最後個Windows recovery partition之外嘅partition全部delete.
之後你可以開一個新partition做data storage又得或者用tool去將佢同現有Windows partition合併又得.
再唔係自己重裝一次Windows時一次過delete partition+合併都得.
或者自己改一改馳為提供個重裝windows 個script等佢自己同你做一樣得咗

以下講解一吓點改馳為提供個重裝windows 個script同用佢個image洗機加改partition(所有資料將被清除)
Step 1(很重要):用系統管理員身份開cmd之後run

DISM.exe /Online /Export-Driver /Destination:"Somewhere here"

複製代碼

去backup啲預載driver並copy去安全的地方。馳為啲image入面唔一定齊driver,唔backup小心揾唔翻
未命名.png

Step 2:Backup all your things
Step 3 :去佢個網到下載返對應嘅image
http://forum.chuwi.com/thread-1157-1-1.html
Step 4:準備一隻usb flash disk 喺無記錯windows7或更新版本format做NTFS或者FAT32嘅partition同時改名做winpe
Step 5:將個下載返嚟嘅檔案解壓放入usb flash disk
未命名.png

Step 6:用notepad去開隻usb flash disk:\Scripts\Main.cmd去將佢改成係唔係都當部機係單系統
大約係改成咁

@echo off
@rem This script is called by x:\Windows\System32\Startnet.cmd - WinPE
@echo.
@echo.
@echo.
@echo.
@rem *******************************************************************
@rem FLASH_BIOS=1 Auto flash BIOS / FLASH_BIOS=0 Do not auto flash BIOS
@rem *******************************************************************
@echo.
set FLASH_BIOS=0
@echo.
@echo Running Intel Optimization powercfg for improved imaging times
@echo.
@echo call powercfg /s 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c
call powercfg /s 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c
@echo.
@echo.
@echo.
@rem *****************************************************************
@rem List all the disks, then search the volumes of each one to see
@rem which disks may have "Winpe" in the label. We will ignore that
@rem disk and use the first disk without the Winpe label that we find.
@rem *****************************************************************
@echo.>x:\Listdisk.txt
@echo list disk>>x:\Listdisk.txt
@echo exit>>x:\Listdisk.txt
@echo call diskpart /s x:\Listdisk.txt
call diskpart /s x:\Listdisk.txt>x:\Disks.txt
@echo.
@rem Set Disk equal to blank to start
set disk=
@echo.
@rem
@rem This line will write a diskpart script to select the disk and detail it's contents.
@rem We use this output to find a disk that does NOT have Winpe as the volume label.
@rem That disk will have the OS installed to it. This way you can exclude USB from diskpart.
@rem
@rem This works around the issue where the USB key is sometimes enumerated as disk 0 and the
@rem SSD is disk 1.
@rem
for /f "skip=8 tokens=2" %%A in (x:\Disks.txt) do (
@echo sel disk %%A>x:\Par.txt
@echo det disk>>x:\Par.txt
@echo exit>>x:\Par.txt
if NOT "%%A"=="DiskPart..." call :ListPar %%A
)
if %Disk%=="" echo No disk found without a volume label of "Winpe"&& set disk=0
@echo Using Disk "%Disk%"
@echo.
@echo *****************************************************************
@rem Map drive letter for Install.wim and Winre.wim
@echo *****************************************************************
@rem Create an output file containing all the drive letters
@echo.>x:\listVol.txt
@echo list volume>>x:\listVol.txt
@echo exit>>x:\listVol.txt
@echo call diskpart /s x:\listVol.txt
call diskpart /s x:\Listdisk.txt>x:\Output.txt
@echo call diskpart /s x:\listVol.txt>x:\Output.txt
diskpart /s x:\listVol.txt>x:\Output.txt
@echo.
@rem Go through each drive letter, looking for the images\Install.txt file
for /f "skip=8 tokens=3" %%A in (x:\Output.txt) do (
if exist %%A:\images\install.txt set InstallPath=%%A:\images&& echo "Found device with images folder and install.txt file"
)
@echo.
@echo.
@echo.
@echo *****************************************************************
@echo Checkup SingleOS or DualOS or whether exist windows partiton
@echo *****************************************************************
@rem create diskpart script for search windows partitions from emmc disk
@echo.>x:\ListPar.txt
@echo select disk "%Disk%" >>x:\ListPar.txt
@echo list partition >>x:\ListPar.txt
@echo exit >>x:\ListPar.txt
@echo.
@rem run diskpart script
diskpart /s x:\ListPar.txt >x:\eMMCPar.txt
@echo.
@rem SingleOS / DualOS switch
find "Partition 6" x:\eMMCPar.txt >nul
if %ERRORLEVEL% NEQ 0 Goto :SingleOS
@rem ensure it's DualOS,and check whether exist windows partition,if not:create the new windows partition
find "Partition 12" x:\eMMCPar.txt >nul
if %ERRORLEVEL% NEQ 0 Goto :SingleOS
@echo.>x:\checkpart.txt
@echo select disk "%Disk%">>x:\checkpart.txt
@echo list partition>>x:\checkpart.txt
@echo exit>>x:\checkpart.txt
@echo call diskpart /s x:\checkpart.txt>x:\outpar.txt
call diskpart /s x:\checkpart.txt>x:\outpar.txt
@echo.
@echo.>x:\DelPar.txt
@echo select disk "%Disk%">>x:\DelPar.txt
for /f "skip=21 tokens=2" %%A in (x:\outpar.txt) do (
if %%A NEQ DiskPart... echo select partition %%A>>x:\DelPar.txt && echo delete partition override>>x:\DelPar.txt
)
echo exit>>x:\DelPar.txt
diskpart /s x:\DelPar.txt
Goto :SingleOS
:SingleOS
@echo.
@echo This is a SingleOS!
@echo.
@echo.
:UEFImode
@echo.
@rem ************************
@rem UEFI SECTION
@rem ************************
@echo The PC is booted in UEFI mode
@echo.>x:\winpart.txt
@echo select disk "%Disk%">>x:\winpart.txt
@echo clean>>x:\winpart.txt
@echo convert gpt>>x:\winpart.txt
@echo create partition efi size=100>>x:\winpart.txt
@echo format quick fs=fat32 label="System">>x:\winpart.txt
@echo assign letter="S">>x:\winpart.txt
@echo create partition msr size=16>>x:\winpart.txt
@echo create partition primary>>x:\winpart.txt
@echo format quick fs=ntfs label="Windows">>x:\winpart.txt
@echo assign letter="W">>x:\winpart.txt
@echo shrink desired=800>>x:\winpart.txt
@echo create partition primary>>x:\winpart.txt
@echo format quick fs=ntfs label="Recovery">>x:\winpart.txt
@echo assign letter="R">>x:\winpart.txt
@echo set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac">>x:\winpart.txt
@echo gpt attributes=0x8000000000000001>>x:\winpart.txt
@echo exit>>x:\WinPart.txt
@echo Winpart.txt now contains.....
@echo.
type x:\winpart.txt
@echo.
@echo.
@echo *****************************************************************
@echo Setting up the partition table
@echo *****************************************************************
@echo call diskpart /s x:\winpart.txt
diskpart /s x:\winpart.txt
@echo.
@echo.
@echo.
@echo.
@rem Check InstallPath was found and there are images in it.
if NOT EXIST %InstallPath%\Install.wim echo "Install.wim NOT found." && goto :Error
@echo Install.wim FOUND at %InstallPath%\images\install.wim
@echo.
@echo.
@echo.
@echo *****************************************************************
@rem Switches to the USB disk
@rem Create folders on local (eMMC) disk and copy files from USB disk
@echo *****************************************************************
@echo.
@echo Making directories...
md w:\recycler\scratch
if %errorlevel% NEQ 0 echo "Failed to make w:\recycler\scratch directory" && goto :error
@echo.
md r:\recovery\windowsre
if %errorlevel% NEQ 0 echo "Failed to make m:\recovery\windowsre directory" && goto :error
@echo.
@echo.
@echo *****************************************************************
@echo Applying the Windows image from the USB
@echo *****************************************************************
@echo call dism /apply-image /imagefile:"%InstallPath%\Install.wim" /index:1 /applydir:w:\ /compact /scratchdir:"w:\recycler\SCRATCH
call dism /apply-image /imagefile:"%InstallPath%\Install.wim" /index:1 /applydir:w:\ /compact /scratchdir:"w:\recycler\SCRATCH
if %errorlevel% NEQ 0 echo "Failed to apply image to w:" && goto :error
@echo.
@echo *****************************************************************
@echo Rund SingleInstance
@echo *****************************************************************
@echo.
if EXIST W:\Recovery\Customizations\USMT.ppkg dism /Apply-CustomDataImage /CustomDataImage:W:\Recovery\Customizations\USMT.ppkg /ImagePath:W:\ /SingleInstance
@echo *****************************************************************
@rem Move WinRE to Recovery Partition
@echo *****************************************************************
@echo.
@echo Modifying attributes of winre.wim so we can move it.
attrib w:\Windows\System32\recovery\winre.wim -s -h -a -r
@echo move w:\Windows\System32\recovery\winre.wim r:\recovery\windowsre
move w:\Windows\System32\recovery\winre.wim r:\recovery\windowsre
if %errorlevel% NEQ 0 echo "Failed to move winre.wim to r:\recovery\windowsre" && goto :error
@echo.
@echo reset attributes now
attrib r:\Recovery\Windowsre\winre.wim +s +h +a +r
@echo.
@echo.
@echo *****************************************************************
@echo Setting the boot environment
@echo *****************************************************************
@echo call w:\WINDOWS\SYSTEM32\BCDBOOT w:\WINDOWS /s s: /f all
w:\WINDOWS\SYSTEM32\BCDBOOT w:\WINDOWS /s s: /f all
if %errorlevel% NEQ 0 echo "Failed to set boot information" && goto :error
@echo.
@echo.
@echo.
@echo *****************************************************************
@echo Setting the recovery environment
@echo *****************************************************************
@echo w:\windows\system32\reagentc /SetREImage /Path r:\RECOVERY\WINDOWSRE /target w:\windows
w:\windows\system32\reagentc /SetREImage /Path r:\RECOVERY\WINDOWSRE /target w:\windows
if %errorlevel% NEQ 0 echo "Failed to set recovery information" && goto :error
@echo.
@echo xcopy W:\Recovery\OEM\sdbus.sys W:\Windows\System32\Drivers\ /y
xcopy W:\Recovery\OEM\sdbus.sys W:\Windows\System32\Drivers\ /y
if %errorlevel% NEQ 0 echo "Failed to Copy sdbus.sys"
@echo.
attrib +H +R W:\Recovery
rmdir /s /q w:\recycler
if "%FLASH_BIOS%"=="1" GOTO :FLASH_BIOS
@echo *****************************************************************
@echo WIMboot image deployment COMPLETE. Type EXIT from Command
@echo Prompt to restart or turn off device.
@echo *****************************************************************
Wpeutil shutdown
color 2f
Goto :END
:FLASH_BIOS
@echo.
@echo *****************************************************************
@echo Flash BIOS
@echo *****************************************************************
@echo.
@echo BIOS file FOUND at %WinPESource%Images\BIOS\*.ROM
@echo.
xcopy /y %WinPESource%Images\BIOS\*.ROM %WinPESource%Scripts\Tools\
for /r "%WinPESource%Scripts\Tools" %%Z in (*.ROM) do (
ren "%%Z" "%%~na.fd"
)
if NOT EXIST %WinPESource%Scripts\Tools\*.fd echo "Can not find the BIOS file" && goto :error
@REM Flash BIOS
%WinPESource%Scripts\Tools\H2OFFT-W.exe
Del /q %WinPESource%Scripts\Tools\*.fd
if %errorlevel% NEQ 0 echo "Failed to flash BIOS" && goto :error
@echo *****************************************************************
@echo WIMboot image deployment COMPLETE. Type EXIT from Command
@echo Prompt to restart or turn off device.
@echo *****************************************************************
color 2f
Goto :END
:ERROR
@echo.
@echo An error has been detected.
color 4f
@echo.
goto :END
:ListPar
@REM This section is to bring a disk number and use it to List Partitions
@echo.
set TempDisk=%1
diskpart /s x:\Par.txt>x:\ParOutput.txt
for /f "skip=24 tokens=3" %%A in (x:\ParOutput.txt) do (
if /i "%%A"=="no" set Disk=%TempDisk%
)
for /f "skip=26 tokens=4" %%A in (x:\ParOutput.txt) do (
if /i NOT "%%A"=="Winpe" set Disk=%TempDisk%
)
Goto :EOF
:END
@rem
@rem Get finish time so we can evaluate total WinPE phase time.
@rem
call |time>x:\StopTime.txt
@rem
@rem Now parse both files to display the Start and Finish Time
@rem
@echo.
@echo.
for /f "tokens=5" %%A in (x:\starttime.txt) do echo Script Start Time is %%A
for /f "tokens=5" %%A in (x:\stoptime.txt) do echo Script Stop Time is %%A
@echo.

複製代碼

Step 7:請確定已備份所有資料後熄咗部Hi8 pro佢
Step 8:用usb hub連接好keyboard, usb flash disk,Hi8 Pro,開機時按F7入boot menu並選擇以usb flash disk開機
Step 9:全自動完成
21-10-2018更新:喚醒筋疲力盡屍體的方法
於24#中,我提到自己部小Hi 8 Pro已經喺今年年頭左右長眠不醒。
但係,近日我成功救返佢啦。咁岩有人問問題,咁我又享吓。
症狀:完全耗電後,長眠不醒。無法充電。
估計病因:電池電壓過底令充電相關IC無法正常識辨電池/運作
庸醫式治療法:拆機直接充粒鋰電
Step1:移除螺絲+由邊位拆機

Step2:駁電線到粒鋰電同叉機

Step3:叉80%左右
Step4:開機
Step5:用部機個usb type-c keep住叉至100%
屍體返生
疑似相關後遺症:部機個usb type-c otg出唔到電,不過可以正常用if另外供電

圖片附件: WP_20160721_19_27_28_Pro.jpg (2016-7-24 20:50, 136.23 KB) / 下載次數 218
https://h1.hkepc.com/forum/attachment.php?aid=1908438&k=d8bd0c1f98a6b829dd1b6aabaa4e2309&t=1782047034&sid=U1OAEfub4d

圖片附件: WP_20160721_19_28_28_Pro.jpg (2016-7-24 20:52, 135.74 KB) / 下載次數 208
https://h1.hkepc.com/forum/attachment.php?aid=1908439&k=60ffdb55539ada16d9ec049f53554d31&t=1782047034&sid=U1OAEfub4d

圖片附件: WP_20160721_19_31_52_Pro.jpg (2016-7-24 20:53, 147.34 KB) / 下載次數 214
https://h1.hkepc.com/forum/attachment.php?aid=1908440&k=e5b76b5731cac27931c9ada07c22f9e3&t=1782047034&sid=U1OAEfub4d

圖片附件: WP_20160721_19_32_00_Pro.jpg (2016-7-24 20:53, 148.55 KB) / 下載次數 199
https://h1.hkepc.com/forum/attachment.php?aid=1908441&k=09c0aa73b903832736b8748c56852628&t=1782047034&sid=U1OAEfub4d

圖片附件: WP_20160721_19_36_50_Pro.jpg (2016-7-24 20:53, 142.88 KB) / 下載次數 239
https://h1.hkepc.com/forum/attachment.php?aid=1908442&k=eaea5f6277a367b65e1bc6b8c1f636d9&t=1782047034&sid=U1OAEfub4d

圖片附件: WP_20160724_20_39_17_Pro.gif (2016-7-24 20:57, 102.35 KB) / 下載次數 204
https://h1.hkepc.com/forum/attachment.php?aid=1908444&k=3bebc47a5af53a2ee3e3dc98d0707e7b&t=1782047034&sid=U1OAEfub4d

圖片附件: WP_20160724_20_42_44_Pro.gif (2016-7-24 20:57, 123.41 KB) / 下載次數 225
https://h1.hkepc.com/forum/attachment.php?aid=1908445&k=cc5a21b585ce315a00e6a03c0ce0e2aa&t=1782047034&sid=U1OAEfub4d

圖片附件: Screenshot_2016-07-24-21-56-04.png (2016-7-24 22:10, 132.1 KB) / 下載次數 202
https://h1.hkepc.com/forum/attachment.php?aid=1908481&k=2cdf6091a6f2fd9b1786d055bd1be715&t=1782047034&sid=U1OAEfub4d

圖片附件: Screenshot_2016-07-24-21-56-27.png (2016-7-24 22:10, 127.97 KB) / 下載次數 232
https://h1.hkepc.com/forum/attachment.php?aid=1908482&k=5bc2573a30897a87880ce6e34283d82f&t=1782047034&sid=U1OAEfub4d

圖片附件: WP_20160724_22_00_44_Pro.jpg (2016-7-24 22:10, 149.66 KB) / 下載次數 214
https://h1.hkepc.com/forum/attachment.php?aid=1908483&k=67ca49dc7f03256be0b4216a8785c606&t=1782047034&sid=U1OAEfub4d

圖片附件: WP_20160724_22_02_16_Pro.jpg (2016-7-24 22:10, 114.87 KB) / 下載次數 215
https://h1.hkepc.com/forum/attachment.php?aid=1908484&k=8ae81381536e96eaa8d8711fbe9f0717&t=1782047034&sid=U1OAEfub4d

圖片附件: 未命名.png (2016-8-12 01:10, 5.47 KB) / 下載次數 259
https://h1.hkepc.com/forum/attachment.php?aid=1912811&k=a5facd1ff50477ae168f4dd070acecbe&t=1782047034&sid=U1OAEfub4d

圖片附件: 未命名.png (2016-8-12 01:15, 23.17 KB) / 下載次數 192
https://h1.hkepc.com/forum/attachment.php?aid=1912814&k=146111cf8bd8da3262904d533e969e14&t=1782047034&sid=U1OAEfub4d

圖片附件: img_20181021_225932.jpg (2018-10-21 23:41, 102.24 KB) / 下載次數 199
https://h1.hkepc.com/forum/attachment.php?aid=2088204&k=4b72f5ceae26571536cf9b2697a86af6&t=1782047034&sid=U1OAEfub4d

圖片附件: e1.jpg (2018-10-21 23:41, 146.06 KB) / 下載次數 195
https://h1.hkepc.com/forum/attachment.php?aid=2088205&k=3ecde7b6fa1e30bad67681e4f0352521&t=1782047034&sid=U1OAEfub4d

圖片附件: e2.jpg (2018-10-21 23:41, 133.71 KB) / 下載次數 209
https://h1.hkepc.com/forum/attachment.php?aid=2088206&k=c2a73157be7e43072747ac75cffe4ae5&t=1782047034&sid=U1OAEfub4d

作者: hood1916 時間: 2016-7-24 22:40

vi8 plus 重置死windows

買個USB C hub搞不如買過部機算
上網聽講係usb 2.0黎

作者: C-Leung 時間: 2016-7-24 23:01

本帖最後由 C-Leung 於 2016-7-24 23:07 編輯

唔識經usb boot，但樓主又係點樣由32bit win10 down去64bit win8.1
經win10個boot override?

其實我覺得呢d雙系統仲衰過以前d純an tab
話就話32g rom，但兩邊os都冇乜位剩，想裝多d野都唔得
如果係64g rom + 可隨意resize(就算只係第一次著機時可以俾你揀都好)兩個os嘅rom size，就實用好多喇

作者: xxxxxx623 時間: 2016-7-24 23:17

唔識經usb boot，但樓主又係點樣由32bit win10 down去64bit win8.1

其實我覺得呢d雙系統仲衰過以前d純 ...
C-Leung 發表於 2016-7-24 23:01

先開機入windows 10之後設定,更新與安全性,復原, 進階啟動,入面揀命令提示字元(command prompt)
之後會重新開機入去部機個windows recovery partition入面個 windows pe
插usb flash disk
先用cmd format咗個windows partition
再開dism倒個windows 8.1(64bit)嘅install.wim落去
再加上bcdboot改個bcd
一部死windows嘅hi8 pro就完成啦

作者: C-Leung 時間: 2016-7-24 23:34

回覆 4# xxxxxx623
高手來

無知一問重刷官方固件幫唔幫到你？

作者: xxxxxx623 時間: 2016-7-25 00:04

回覆 xxxxxx623
高手來

無知一問重刷官方固件幫唔幫到你？
C-Leung 發表於 2016-7-24 23:34

理論上幫到
官方重刷windows方法大約係
usb hub + keyboard+usb flash disk+入windows pe+自動用dism倒windows+自動用bcdboot砌bcd

不過因為我未有usb hub所以無法插住usb flash disk同時開機時keyboard按f7入boot menu去boot入windows pe

作者: percy11 時間: 2016-7-31 12:38

ching, 想問一問, 有否試過Android的google play在香港能用到嗎? 因為我問過那邊客服, 他們只說google play 在內地不能使用, 其他不知道.

另外, 我又聽聞Hi8 pro 因為只得32G+2G, Windows大既只分到不到20G, 如果改為64bit Windows, 會用盡所有所有記憶體, 除非刪除Android, 否則不可行, 這是否可以解決?

作者: xxxxxx623 時間: 2016-7-31 22:24

ching, 想問一問, 有否試過Android的google play在香港能用到嗎? 因為我問過那邊客服, 他們只說google play ...
percy11 發表於 2016-7-31 12:38

Google Play 我無試過,因為嘗試裝Windows 8.1中我嘅誤操作已經殺咗個Android啦
雖然可以再flash返,不過我主力Windows
另外部機可以自行改成純Android或者純Windows去用盡32GB
不過再一次提醒,一如一開始所講此機不支援64bit OS

作者: percy11 時間: 2016-8-1 23:26

Google Play 我無試過,因為嘗試裝Windows 8.1中我嘅誤操作已經殺咗個Android啦
雖然可以再flash返,不過 ...
xxxxxx623 發表於 2016-7-31 22:24

明白，謝謝！

作者: 0742 時間: 2016-8-3 10:01

ching, 想問一問, 有否試過Android的google play在香港能用到嗎? 因為我問過那邊客服, 他們只說google play ...
percy11 發表於 2016-7-31 12:38

問上面客服話冇 google play。

作者: Hiroring 時間: 2016-8-3 10:28

有google play, 即系冇问题糸香港用，更新google 后就可以啦，！。
如果部机，安卓个边有twrp 可刷入去root 机，安卓可用性很大，以第一代双系统vi8 为例！

作者: Hiroring 時間: 2016-8-3 10:31

所以，舊版有時着数多多，以弛为vi8, 酷比魔方T8，talk9x 等等

作者: erichk32 時間: 2016-8-7 19:19

回覆 1# xxxxxx623

ching 可唔可以PM條LINK, 我搵唔到489包埋KEYBOARD>.<

作者: xxxxxx623 時間: 2016-8-7 19:36

回覆 xxxxxx623

ching 可唔可以PM條LINK, 我搵唔到489包埋KEYBOARD>.
erichk32 發表於 2016-8-7 19:19

已pm
記住如因usb type c可能係usb 3.0而想買就請務必小心
因為佢個usb好怪,usb3.0未必detect到,要當2.0用
而家未有活動所以只有499包keyboard同原裝皮套
據聞八月生產嘅機已有64bit bios(serial number after Hi8 PQ64G221608XXXXX)
祝你好運

作者: kcthomlau 時間: 2016-8-7 19:46

呢個kb用過舊電斷航差

作者: mike1314 時間: 2016-8-8 16:18

已pm
記住如因usb type c可能係usb 3.0而想買就請務必小心
因為佢個usb好怪,usb3.0未必detect到,要當2.0 ...
xxxxxx623 發表於 2016-8-7 19:36

ching可唔可以話我知邊到買謝謝

via HKEPC Reader for Android

作者: dcoloane 時間: 2016-8-8 16:44

ching 可唔可以PM我條LINK，thx

作者: prodigalng 時間: 2016-8-9 16:25

我心大心細買hi8pro 好定係台電x80power
hi8pro個mon光D同清D 台電x80power 就個樣靚仔D

作者: simonlau44 時間: 2016-12-2 22:28

本帖最後由 simonlau44 於 2016-12-3 16:47 編輯

感謝xxxxxx623的教學, 令我成功把雙11 掏回來的 hi 8pro 刷成單 win10. 有幾點想講

1. 刷image 用了一個小時有多, 幾慢下,差滿電先好刷
2. 雙11皮套鍵盤要問客服先會送
3. 刷image 後Win10 沒有繁中語言選擇 (Win10是 1605 32bit 版)
4. 單系統下整個空間有約28.9GB, 17GB Free
5. 可裝 win 10 anniversary update, 裝完wifi 會死左, 要 uninstall + remove driver software+ 重裝 SDIO driver (chuwi forum 有) 就回復正常, cleanup 完仲有15.2GB Free

作者: PMIII 時間: 2017-1-15 23:50

想問hi8 pro的bios最後都是無法解決boot usb手指嗎?

作者: xxxxxx623 時間: 2017-1-16 00:16

想問hi8 pro的bios最後都是無法解決boot usb手指嗎?
PMIII 發表於 2017-1-15 23:50

有usb type-c adapter + usb hub +usb keyboard 就可以
官方教程
http://pan.baidu.com/s/1hs1Dz4g#list/path=%2F

作者: Mathk 時間: 2017-1-16 20:13

外國forum有啲tools override個uefi去行64bits

作者: ncarleton 時間: 2018-5-12 16:43

提示: 作者被禁止或刪除內容自動屏蔽

作者: xxxxxx623 時間: 2018-5-12 22:43

c hing, 你claim 的"此机有64bit CPU, 但不支援 64bit OS", 你無錯.

但我只係想指出.

ALL of the ...
ncarleton 發表於 2018-5-12 16:43

個post咁老你都揾到嚟回覆,再加上我部小Hi 8 Pro已經喺今年年頭左右長眠不醒
有人提返起佢真係令我好感動

咁我話返你知馳為之後係有出同樣行Z8300小atom嘅64bit windows版Hi 8 Pro
但係馳為無為我地啲舊機主提供64bit uefi update
另外,內置個Android係行64bit
我只係想指出馳為出品啲軟硬件同after sales service都唔多掂
當然仲有其它廠出e.g.昂達oBook 10
為玩機準備？昂達oBook 10雙系統版評測
http://sina.com.hk/news/article/ ... %B8%AC-5643349.html

如果有人以為世界上係無Z8300小atom行64bit windows+Andorid嘅雙系統tablet,
咁係嗰位師兄閱歷太少了.

題外話
M$ store HK可以用死tablet trade in,部小Hi 8 Pro可以trade 到$50
trade in去買xbox one s可以減多$500
好想買部返嚟播UHD Blu-ray

作者: chue 時間: 2018-5-12 23:08

改單 OS 的話應選改成 ANDROID,WIN10 就算食晒全部 SPACE 都唔夠用,個系統太大食

作者: ncarleton 時間: 2018-5-13 10:09

提示: 作者被禁止或刪除內容自動屏蔽

作者: AngusMa 時間: 2018-10-20 17:50

部Hi8 pro的Windows 10成日彈出update, 但update 時又話C不夠位, 於是上網找方法, 看見樓主xxxxxx623教改成單 win10, 我跟住用tool 把Windows以外的partition全部delete同合併,便成功update.

但還有以下的問題:-
1) 在檔案管理內多了一個System(F:),但打不開的沒有權限存取, 應該是之前一個EFI partition, 是FAT32大約100MB, 請問可否改番無標籤和隐藏?
2) 雖然改了單Windows系統, 但開機時還是如之前一樣從10倒數(選系統), 請問怎樣改可開機直入Windows?

作者: xxxxxx623 時間: 2018-10-21 22:21

部Hi8 pro的Windows 10成日彈出update, 但update 時又話C不夠位, 於是上網找方法, 看見樓主xxxxxx623教改成 ...
AngusMa 發表於 2018-10-20 17:50

1)可以, just remove the letter assigned
https://winaero.com/blog/remove-drive-letter-windows-10/

2)唔覺有方法

作者: Botti 時間: 2019-7-4 08:33

17年尾買，玩左陣放埋
早幾星期搵返，想up windows話唔夠位，
把心一橫，改單系統，過程順利，

記住差夠電等佢行自動波。

但點解讀唔到sdcard ? 試過***32/sandisk 128 都唔得，有無用家有同樣問題 ?

作者: xxxxxx623 時間: 2019-7-4 20:01

17年尾買，玩左陣放埋
早幾星期搵返，想up windows話唔夠位，
把心一橫，改單系統，過程順利，

記住差夠電 ...
Botti 發表於 2019-7-4 08:33

driver?

作者: Botti 時間: 2019-7-5 08:37

driver?
xxxxxx623 發表於 2019-7-4 20:01

check 左 device manager 已是最新
上網睇 history ，一大堆人 x 呢樣野...馳為當睇唔到

算...開住 onedrive 用 ...

作者: tcw 時間: 2019-7-5 21:59

回覆 30# Botti

唔夠電...插電用吧...